Initial class construction

Git/usr/share/vim/vim81/spell/check_locales.vim

@@ -0,0 +1,21 @@
+" Script to check if all the locales used in spell files are available.
+
+grep /sys env LANG/ */main.aap
+let not_supported = []
+for item in getqflist()
+  let lang = substitute(item.text, '.*LANG=\(\S\+\).*', '\1', '')
+  try
+    exe 'lang ' . lang
+  catch /E197/
+    call add(not_supported, lang)
+  endtry
+endfor
+
+if len(not_supported) > 0
+  echo "Unsupported languages:"
+  for l in not_supported
+    echo l
+  endfor
+else
+  echo "Everything appears to be OK"
+endif

Git/usr/share/vim/vim81/spell/cleanadd.vim

@@ -0,0 +1,32 @@
+" Vim script to clean the ll.xxxxx.add files of commented out entries
+" Author:	Antonio Colombo, Bram Moolenaar
+" Last Update:	2008 Jun 3
+
+" Time in seconds after last time an ll.xxxxx.add file was updated
+" Default is one second.
+" If you invoke this script often set it to something bigger, e.g. 60 * 60
+" (one hour)
+if !exists("g:spell_clean_limit")
+  let g:spell_clean_limit = 1
+endif
+
+" Loop over all the runtime/spell/*.add files.
+" Delete all comment lines, except the ones starting with ##.
+for s:fname in split(globpath(&rtp, "spell/*.add"), "\n")
+  if filewritable(s:fname) && localtime() - getftime(s:fname) > g:spell_clean_limit
+    if exists('*fnameescape')
+      let s:f = fnameescape(s:fname)
+    else
+      let s:f = escape(s:fname, ' \|<')
+    endif
+    silent exe "tab split " . s:f
+    echo "Processing" s:f
+    silent! g/^#[^#]/d
+    silent update
+    close
+    unlet s:f
+  endif
+endfor
+unlet s:fname
+
+echo "Done"

Git/usr/share/vim/vim81/spell/fixdup.vim

@@ -0,0 +1,30 @@
+" Vim script to fix duplicate words in a .dic file  vim: set ft=vim:
+"
+" Usage: Edit the .dic file and source this script.
+
+let deleted = 0
+
+" Start below the word count.
+let lnum = 2
+while lnum <= line('$')
+  let word = getline(lnum)
+  if word !~ '/'
+    if search('^' . word . '/', 'w') != 0
+      let deleted += 1
+      exe lnum . "d"
+      continue		" don't increment lnum, it's already at the next word
+    endif
+  endif
+  if lnum%1000 == 0
+    echon "\r Processing line ".lnum. printf(" [ %02d%%]", lnum*100/line('$'))
+  endif
+  let lnum += 1
+endwhile
+
+if deleted == 0
+  echomsg "No duplicate words found"
+elseif deleted == 1
+  echomsg "Deleted 1 duplicate word"
+else
+  echomsg printf("Deleted %d duplicate words", deleted)
+endif

Git/usr/share/vim/vim81/spell/he.vim

@@ -0,0 +1,10 @@
+" For Hebrew capitals should not be checked.  But only change the
+" 'spellcapcheck' option when it is not at its default value.
+let s:spc = &l:spc
+setlocal spc&
+if s:spc == &l:spc
+  setlocal spc=
+else
+  let &l:spc = s:spc
+endif
+unlet s:spc

Git/usr/share/vim/vim81/spell/spell.vim

@@ -0,0 +1,4 @@
+" Settings for when generating spellfiles.
+"
+" Assume we have 2 Gbyte RAM available.
+set mkspellmem=1800000,6000,1600

Git/usr/share/vim/vim81/spell/yi.vim

@@ -0,0 +1,10 @@
+" For Yiddish capitals should not be checked.  But only change the
+" 'spellcapcheck' option when it is not at its default value.
+let s:spc = &l:spc
+setlocal spc&
+if s:spc == &l:spc
+  setlocal spc=
+else
+  let &l:spc = s:spc
+endif
+unlet s:spc